h dftactgrp(*no)  actgrp(*CALLER)  bnddir('QC2LE')
      *---------------------------------------------------------------
      *  David Malle
      *  Objet : User Space -> taille extensible
      *---------------------------------------------------------------
      * pUsrSpaceName  : UserSpace + Bibliothèque
      *
      * USPEXTEND - Rend un User Space re-taillable automatiquement
      *-------------------------------------------------------------------------
     D EntryParms      PR                  extpgm('USPEXTEND')
     D  pUsrSpaceName                20A
     D EntryParms      PI
     D  pUsrSpaceName                20A
      *‚------------------------------------------------------------------------
      *‚Procédure de gestion des erreurs
      *‚------------------------------------------------------------------------
     D ErrorHdlr       Pr                  ExtPgm('ERRHDLR')
     D  DumpText                     12A   const
      *‚------------------------------------------------------------------------
      *‚ API : Gestion des UserSpaces
      *‚------------------------------------------------------------------------
      *‚IBM API QUSCUSAT changement des attributs d'un User Space.
     D QUSCUSAT        PR                  ExtPgm('QUSCUSAT')
     D   RetLib                            like(ReturnLib)
     D   UsrSpc                            like(pUsrSpaceName)
     D   AttrList                          like(ChangeAttr)
     D   ErrorCode                         like(ErrorDS)
     D*‚DS pour rendre la taille du User Space extensible
      *‚ Number_Attr = Nombre d'attributs (1)
      *‚ définition de l'attribut :
      *‚    Attr_Key = Attribut à modifier (3=Extensible)
      *‚    Attr_Siz = Longueur de l'attribut (1)
      *‚    Attr_Dta = Nouvelle valeur de l'attribut (1="Oui")
     D ChangeAttr      DS
     D   Number_Attr                 10I 0 Inz(1)
     D   Attr_Key                    10I 0 Inz(3)
     D   Attr_Siz                    10I 0 Inz(1)
     D   Attr_Dta                     1    Inz('1')
      *‚ DS Erreur
     D ErrorDS         DS
     D  BytesProvided                10I 0 inz(%size(ErrorDS))
     D  BytesAvail                   10I 0 inz(0)
     D  MessageID                     7A
     D  Reserved1A                    1A
     D  MessageData                 240A
      *‚------------------------------------------------------------------------
      *‚Variables locales
      *‚------------------------------------------------------------------------
     d ReturnLib       s             10A
      *-------------------------------------------------------------------------
      * Début des traitements
      *-------------------------------------------------------------------------
      /free
         QUSCUSAT(ReturnLib:pUsrSpaceName:ChangeAttr:ErrorDS);
         If BytesAvail > 0;
           ErrorHdlr('USPEXTEND');
         endif;
         *inlr = *on;
      /end-free